有预应力的谐响应分析只能用缩减法和模态叠加法进行。

• 若用缩减法进行有预应力的谐响应分析，首先要进行静力学分析结算结构的预应力，再进行谐响应分析。
• 若用模态叠加法进行有预应力的谐响应分析，应当先进行有预应力模态分析，再进行一般的模态叠加法谐响应分析。

问题描述

一个紧绷的吉他弦，长度为l，直径为d，受轴向拉力F1，琴弦为E调的C(do)。在四分之一处用力F2弹击。计算弦的一阶固有频率，并验证仅当弹击力的频率为弦的奇数阶固有频率时才会产生谐响应。

分析概述

使用单元的应力刚化效应，利用谐响应分析求解侧向力F2的位移响应。使用POST26后处理显示谐响应结果。

命令流

/PREP7
/TITLE, HARMONIC RESPONSE OF A GUITAR STRING, WWW.MEKENICAL.COM
ANTYPE,STATIC       ! STATIC ANALYSIS, PRESTRESS
ET,1,LINK1          ! TWO-DIMENSIONAL SPAR
R,1,50671E-12       ! CROSS-SECTIONAL AREA OF STRING
MP,EX,1,190E9       ! MATERIAL, STAINLESS STEEL
MP,DENS,1,7920
N,1                 ! DEFINE NODES
N,31,.71
FILL
E,1,2               ! DEFINE ELEMENTS
EGEN,30,1,1
D,1,ALL             ! BOUNDARY CONDITIONS AND LOADING
D,2,UY,,,31
F,31,FX,84
FINISH
/SOLU    
PSTRES,ON           ! DEFINE AS PRESTRESSED ANALYSIS
OUTPR,BASIC,1
SOLVE
FINISH
/SOLU    
ANTYPE,MODAL        ! MODAL ANALYSIS
MODOPT,SUBSP,6      ! SUBSPACE ITERATION METHOD, 6 FREQ.
PSTRES,ON           ! PRESTRESSED ANALYSIS
DDEL,2,UY,30
SOLVE
FINISH
/SOLU    
ANTYPE,HARMIC       ! HARMONIC RESPONSE ANALYSIS
HROPT,MSUP,6        ! MODE SUPERPOSITION
HROUT,OFF           ! AMPLITUDE, PHASE ANGLE PRINTOUT
PSTRES,ON           ! PRESTRESSED ANALYSIS
FDELE,31,FX         ! DELETE STRETCH LOAD
F,8,FY,-1           ! FORCE AT X=.1657, NEAR QUARTER POINT
KBC,1               ! STEP CHANGE FORCE
HARFRQ,,2000        ! OBTAIN FREQUENCY EVERY EIGHT HERTZ
NSUBST,250
OUTPR,,NONE
OUTRES,,1
SOLVE
FINISH
/POST26             ! TIME-HISTORY POSTPROCESSOR
FILE,,rfrq          ! REDUCED FREQUENCIES FILE
NSOL,2,16,U,Y,DISP  ! RETRIEVE STRING MIDPOINT DISPLACEMENT RESPONSE
PRVAR,2
/AXLAB,Y,AMPL
PLCPLX,0            ! DISPLAY AMPLITUDE OF COMPLEX VARIABLE (DEFAULT)
PLVAR,2