问题描述 

一弹性密封圈，求解它受一定压缩量情况下的应力。

求解代码

/PREP7
/TITLE,WWW.MEKENICAL.COM
ET,1,PLANE182,,,1 ! 2-D Axisymmetric 4-NODE STRUCTURAL SOLID
MP,EX,1,2.82 ! YOUNG'S MODULUS [MPA]
MP,NUXY,1,0.49967 ! POISSON'S RATIO
C10 = 0.293
C01 = 0.177
NU1 = 0.49967
DD = 2*(1-2*NU1)/(C10+C01)
TB,HYPER,1,1,2,MOONEY
TBDATA,1,C10,C01,DD

K,1
K,2,0.333,0
K,3,0.867,0.867
K,4,1.1,0.867
K,5,1.1,1
K,6,0.8,1
K,7,0.267,0.133
K,8,0,0.133
L,1,2
*REPEAT,7,1,1 ! 将L,1,2命令重复7次
L,8,1
LFIL,1,2,0.20
LFIL,2,3,0.15
LFIL,5,6,0.20
LFIL,6,7,0.15
LFIL,7,8,0.05
LFIL,8,1,0.05
AL,ALL ! 应用所有选择的线生成面
K,25,-0.6,0
K,26,1.1,0
K,27,-0.6,1.0
K,28,1.1,1.0
LSTR,26,25 ! L9
LSTR,27,28 ! L10
! *** 基体分网 ***
LESIZE,8,,,2
LESIZE,13,,,4
LESIZE,14,,,4
ESIZE,0.035
TYPE,1
MAT,1
AMESH,ALL
SAVE,SEAL,DB
!创建接触对，先定义单元和接触参数
ET,2,169 ! TARGET169 2D TARGET SEGMENT
ET,3,171 ! CONTA171 2D SURFACE TO SURFACE CONTACT
MP,MU,1,0 ! 用材料特性定义摩擦，本例先无摩擦计算然后再有摩擦计算，比较结果。有摩擦时设置为0.2
R,1,,,0.1,0.1 ! 用实常数定义接触高级选项对于弯曲为主的问题，采用接触刚度FKN = 0.1作为初始估计值, FTOLN = 0.1 LAGRANGE穿透比例系数（缺省值）
R,2,,,0.1,0.1 ! 如果FKN = 1.0则不收敛
TYPE,2 ! 目标面1 TARGET169
REAL,1 ! TARGET169的实常数
MAT,1 ! 接触面1定义材料与超弹单元同
LESIZE,15,,,1 ! 目标面1（L15）分网尺寸(图5－3)
LMESH,15 ! 目标面1（L15）分网,采用自动分网，此刚性面自动约束。检查外法线方向【OK】
! *** 接触面1：实常数（与目标面1一致）、分网 LSEL,S,LINE,,1,3,1 ! 选L1,L2,L3
LSEL,A,LINE,,9,10,1 ! 再加L9,L10
LSEL,A,LINE,,14 ! 再加L14
NSLL,S,1 ! 选择和所选线相连系的节点
TYPE,3 ! CONTA171这里未发布REAL,1，实常数未重新定义就是前面的REAL,1，MAT也是前面的MAT, 1
ESURF ! 生成接触单元
LSEL,ALL
! *** 检查外法线方向【OK】 ***
! *** 创建接触对2 ***
TYPE,2 ! 目标面2 TARGET169
REAL,2 ! MAT未重新定义，就是前面的MAT, 1
LESIZE,16,,,1 ! 目标面2
LMESH,16 ! L16分网（目标2分网）
KMESH,27 ! 指定PILOT点
TYPE,3 ! 接触面2 CONTA171 REAL,2； MAT,1
LSEL,S,LINE,,5,7, 1 ! 选L5, L6, L7
LSEL,A,LINE,,11,13,1 ! 再加L11,L12,L13
NSLL,S,1
ESURF ! 生成接触单元,其REAL,2； MAT,1
LSEL,ALL
NSEL,ALL
! 刚性面1 被约束
! 刚性面2 随PILOT点移动
! L4对称约束
DL,4,,UX,0
N_LOAD=NODE(KX(27),KY(27),0) ! 为定义刚性面2的位移做准备
FINISH
!定义求解选项和载荷步
/SOLU
NLGEOM,ON
SOLC,ON ! N.L求解自动控制打开（缺省）
TIME,0.85 ! 载荷步、结束时间
D,N_LOAD,UY,-0.85
NSUBST,25,500,10
OUTRES,ALL,ALL
MONITOR,VAR3,N_LOAD,FY
SOLVE
FINISH
!查看结果
/POST1
PLDISP,2 ! 变形图
PLNSOL,S,EQV,0,1 ! VON MISES 应力云图
PLNSOL,CONT,PRES,0, ! 接触压力图
PLNSOL,EPTO,EQV ! 绘等效总应变图5－4
FINISH

 说明

本实例来源于网络，这里做了一些修改，原来的代码中使用的是HYPER56单元，但是在ANSYS11中已经没有这个单元了，这里使用的是2D轴对称单元PLANE182。并且材料属性做了修改。

完整代码下载：

弹性密封圈压缩分析ANSYS命令流