本例对一个弹簧卡子进行接触分析，计算将卡头压进卡座和拉出卡座所需要的力。

/PREP7! 进入前处理器
/TITLE,PLASTIC SNAP-FIT CONNECTOR! 定义工作标题
ET,1,42,,,3! 定义单元类型
ET,2,42,,,3! 定义单元类型
MP,EX,1,2.8E3! 输入弹性模量
R,1,5! 定义实常数
ET,3,48,,,1! 定义单元类型

K,1,10! 生成关键点
K,2,20
K,3,15,18.5
K,4,10,20
K,5,12.5,30
K,6,20,30

L,1,3!  由关键点生成线段
L,3,4
L,4,5
L,5,6
L,6,2
L,2,1
AL,ALL! 由线段生成面

LGEN,2,1,3,1! 生成线段 
K,11,5 ! 生成关键点
K,12,5,30
L,11,7!  由关键点生成线段
L,11,12
L,12,10
LSLA,S  ! 选择面上的所有线段
LSEL,INVERT! 反向选择线段
AL,ALL! 由线段生成面
LSEL,ALL ! 选择所有实体
RECTNG,0,15,0,10 ! 生成矩形面
ASBA,2,3  ! 面相减

AGEN,2,4,,,0,30,0,,0,1! 生成面
ASEL,S,,,4
AATT,1,1,2 !
ASEL,ALL

ESIZE,4! 设置单元尺寸
AMESH,ALL
FINI

/SOLUTION ! 进入求解器
NSEL,S,LOC,Y,0 ! 选择节点
D,ALL,ALL! 施加位移约束
NSEL,S,LOC,Y,60! 选择节点
D,ALL,UY
NSEL,R,LOC,X,5
D,ALL,UX
NSEL,ALL! 选择所有节点
FINI

/PREP7 ! 进入前处理器
MP,MU,3,0.2 ! MU表示摩擦系数
R,3,6E3!实常数（法向刚度）
R,4,6E3

LSEL,S,,,9! 选择线段
LSEL,A,,,17
NSLL,S,1! 选择线段上所有节点
CM,SNAPINS,NODE! 创建节点组元
LSEL,S,,,3
NSLL,S,1
CM,SNAPPRG,NODE
LSEL,S,,,8
NSLL,S,1
CM,PULLINS,NODE
LSEL,S,,,2
NSLL,S,1
CM,PULLPRG,NODE
LSEL,ALL
NSEL,ALL
TYPE,3! 指定单元类型参考号
MAT,3! 指定材料参考号
REAL,3! 指定实常数参考号
GCGEN,SNAPINS,SNAPPRG
GCGEN,SNAPPRG,SNAPINS
REAL,4
GCGEN,PULLINS,PULLPRG
GCGEN,PULLPRG,PULLINS
FINI

/SOLU ! 进入求解器
PRED,ON
AUTOT,ON! 打开自动时间步长
NSUBST,10,100,5! 指定计算子步长
OUTRES,ALL,ALL! 存储全部求解结果

NSEL,S,LOC,Y,60! 选择节点
D,ALL,UY,-30 ! 施加位移荷载
NSEL,ALL! 选择所有实体
SOLVE! 开始求解计算

NSEL,S,LOC,Y,60! 选择节点
D,ALL,UY,-27  ! 施加位移荷载
NSEL,ALL ! 选择所有实体
LNSR,ON
SOLV  ! 开始求解计算
FINI

/POST1 ! 进入POST1后处理器
SET,LIST
SET,,,,,0.8
ESEL,S,TYPE,,3
ETABLE,ST,NMISC,1
ETABLE,GAP,NMISC,3
ETABLE,LENGTH,NMISC,4
ESEL,S,ETAB,ST,1,2
ESORT,ETAB,GAP,1
PRETAB
ESEL,ALL
/DSCAL,,1
/PLOPS,MINM,0
/EDGE,,1

ESEL,U,TYPE,,3
SET,FIRST
PLDI
/USER
SET,,,,,0.8
PLNS,S,EQV
/CONT,,,USER
FINI

/POST26 ! 进入POST26后处理器
NSOL,2,44,U,Y,DISP  ! 定义节点变量
RFOR,3,44,F,Y
RFOR,4,59,F,Y
RFOR,5,56,F,Y
ADD,6,3,4,5,FORCE
ADD,2,2,,,,,,,-1
XVAR,2! 定义X轴显示变量
PLVA,6 ! 曲线显示变量
FINI