在ANSYS的PSD分析中，可以施加压力谱，但压力谱和位移谱、速度谱、加速度谱的处理方式是不一样的。压力谱PSD分析的具体方法是：

1. 在模态分析时，就将压力施加在相应位置（先施加压力载荷，再进行模态分析）；
2. 在PSD分析时，定义谱的类型为PRESS(命令：PSDUNIT,PRESS)；
3. 定义压力谱表（与力谱和地震谱类似）；
4. 选出施加压力的单元所在的节点，用LVSCALE,SCALE施加压力激励；（用模态分析时形成的载荷矢量），可以给定一个比例系数调整压力激励的大小；
5. 指定激励类型为节点激励，命令PFACT,1,NODE；
6. 给定PSD计算控制选项。

其它选项、方法与地震谱和力谱PSD方法一样，步骤和分析过程也相同。

附一个压力谱PSD分析的命令流文件：

/TITLE,ANALYSIS FOR PSD WITH PRESSURE SPECTRUM
/PREP7
ET,1,SHELL63
ET,2,BEAM4
R,1,0.002
R,2,1.6E-5,2.133E-11,2.133E11,4E-3,4E-3
MP,EX,1,2E11
MP,DENS,1,7.8E3
MP,NUXY,1,0.3
K,1
K,2,,,1
LSTR,1,2
TYPE,2
MAT,1
REAL,2
LESIZE,ALL,,,3,1
LMESH,ALL
LGEN,2,ALL,,,,0.5,,,0
LGEN,2,ALL,,,0.5,,,,0
A,2,6,8,4
TYPE,1
MAT,1
REAL,1
ALLSEL,BELOW,AREA
LESIZE,ALL,,,5,1
AMESH,1
ALLS
NUMMGR,ALL,,,
NUMCMP,ALL
NSEL,R,LOC,Z,0
D,ALL,,,,,,ALL
ALLSEL,ALL
ASEL,S,LOC,Z,1
SFA,ALL,,PRES,1
ALLSEL,ALL
SAVE
FINISH
/SOLU
ANTYPE,MODAL
MODOPT,LANB,10,0,100,,OFF,,0
SAVE
SOLVE
FINISH
/SOLU
ANTYPE,MODAL
EXPASS,ON
MXPAND,10,,,YES
SAVE
SOLVE
FINISH
/SOLU
ANTYPE,SPECTR
SPOPT,PSD,,YES
PSDUNIT,1,PRES,,
PSDFRQ,1,,0.5,1.0,2.4,3.8,17
PSDFRQ,1,,18,20,32,,
PSDVAL,1,0.01E6,0.02E6,0.016E6,0.02E6,0.005E6
PSDVAL,1,0.01E6,0.015E6,0.01E6,,
NSEL,S,LOC,Z,1
LVSCALE,1
ALLSEL,ALL
PFACT,1,NODE
PSDRES,DISP,ABS
PSDRES,VELO,ABS
PSDRES,ACEL,ABS
SOLVE
FINISH
/SOLU
ANTYPE,SPECTR
PSDCOM,0.005,10
SOLVE
FINISH
/POST26
STORE,PSD,1
NSOL,2,30,U,Z,UZ30
RPSD,3,2,,1,1,DISP_PSD
RPSD,4,2,,2,1,VELO_PSD
RPSD,5,2,,3,1,ACCE_PSD
PLVAR,2
PLVAR,3
PLVAR,4
PLVAR,5