/PREP7

!*******************定义节点**********************

!*********************塔**************************
!*******************塔上部************************
*DO,I,54.5,33.5,-0.5
K,110-I*2,-(82.1495+I)/7.403322,I,0
*ENDDO

!*******************塔下部************************
!*远朝
!*上
*DO,I,33,0,-0.5
K,110-I*2,-15.6213*I/33.5,I,7.4839*I/33.5-7.4839
*ENDDO
!*下
*DO,I,-0.5,-2.5,-0.5
K,110-I*2,-2.7978*I/6,I,-I/2-7.4839
*ENDDO

!*近朝
!*上
*DO,I,33,0,-0.5
K,182-I*2,-15.6213*I/33.5,I,-7.4839*I/33.5+7.4839
*ENDDO
!*下
*DO,I,-0.5,-2.5,-0.5
K,182-I*2,-2.7978*I/6,I,I/2+7.4839
*ENDDO

!*********桥面(配跨为曲线)******
K,192,-2,0,-6
K,193,0,0,-6
K,194,2,0,-6
K,195,9,0,-6

*DO,I,196,205
K,I,(I-195)*9+9,0,-6
*ENDDO
K,206,105,0,-6

K,207,-2,0,6
K,208,0,0,6
K,209,2,0,6
K,210,9,0,6

*DO,I,211,220
K,I,(I-210)*9+9,0,6
*ENDDO
K,221,105,0,6

!****************背索锚碇*******************
K,222,-31,0,14
K,223,-31,0,-14

!***********************定义单元**********************
!上部塔的截面几何特性
*DIM,BBS,,43
*DIM,HHS,,43
*DIM,SSS,,43
*DIM,IIYYS,,43
*DIM,IIZZS,,43

*DO,I,1,43
BBS(I)=1.5*(I-1)/42+3
HHS(I)=(I-1)/21+3
SSS(I)=BBS(I)*HHS(I)
IIZZS(I)=BBS(I)*HHS(I)**3/12
IIYYS(I)=HHS(I)*BBS(I)**3/12
*ENDDO

!**********平均**********
*DIM,BS,,42
*DIM,HS,,42
*DIM,SS,,42
*DIM,IYYS,,42
*DIM,IZZS,,42
*DO,I,1,42
HS(I)=(HHS(I)+HHS(I+1))/2
BS(I)=(BBS(I)+BBS(I+1))/2
SS(I)=(SSS(I)+SSS(I+1))/2
IYYS(I)=(IIYYS(I)+IIYYS(I+1))/2
IZZS(I)=(IIZZS(I)+IIZZS(I+1))/2
*ENDDO

!下部塔的截面几何特性
*DIM,BBX,,80
*DIM,HHX,,80
*DIM,SSX,,80
*DIM,IIYYX,,80
*DIM,IIZZX,,80

*DO,I,1,80
BBX(I)=2.5
HHX(I)=(I-1)*4.7164/79+5
SSX(I)=BBX(I)*HHX(I)
IIZZX(I)=BBX(I)*HHX(I)**3/12
IIYYX(I)=HHX(I)*BBX(I)**3/12
*ENDDO

!**********平均**********
*DIM,BX,,79
*DIM,HX,,79
*DIM,SX,,79
*DIM,IYYX,,79
*DIM,IZZX,,79
*DO,I,1,79
BX(I)=(BBX(I)+BBX(I+1))/2
HX(I)=(HHX(I)+HHX(I+1))/2
SX(I)=(SSX(I)+SSX(I+1))/2
IYYX(I)=(IIYYX(I)+IIYYX(I+1))/2
IZZX(I)=(IIZZX(I)+IIZZX(I+1))/2
*ENDDO

!******定义单元类型-1-42---塔上部******
*DO,I,1,42
ET,I,BEAM4
MP,EX,I,3.4E10
MP,DENS,I,2.5E3
MP,PRXY,I,0.3
R,I,SS(I),IZZS(I),IYYS(I),BS(I),HS(I)
*ENDDO

!******定义单元类型-43-115---塔下部******
*DO,I,43,114
ET,I,BEAM4
MP,EX,I,3.4E10
MP,DENS,I,2.5E3
MP,PRXY,I,0.3
R,I,SX(I-42),IZZX(I-42),IYYX(I-42),BX(I-42),HX(I-42)
*ENDDO

!******定义单元类型-115---桥面-1******
ET,115,SHELL63
MP,EX,115,3.4E10
MP,DENS,115,2.5E3
MP,PRXY,115,0.3
R,115,1,,,,,

!******定义单元类型-116---桥面-2******
ET,116,SHELL63
MP,EX,116,3.4E10
MP,DENS,116,2.5E3
MP,PRXY,116,0.3
R,116,4,,,,,

!******定义单元类型-117---桥面-3******
ET,117,SHELL63
MP,EX,117,3.4E10
MP,DENS,117,2.5E3
MP,PRXY,117,0.3
R,117,1,,,,,

!******定义单元类型-118-119---背索******
*DIM,CABLE_STRAIN_BS,,2

CABLE_STRAIN_BS(1)=3.978873577E-3 !2500
CABLE_STRAIN_BS(2)=3.978873577E-3 !2500

ET,118,LINK10
MP,EX,118,2E11
MP,DENS,118,7.85E3
MP,PRXY,118,0.3
R,118,0.031416,CABLE_STRAIN_BS(1)

ET,119,LINK10
MP,EX,119,2E11
MP,DENS,119,7.85E3
MP,PRXY,119,0.3
R,119,0.031416,CABLE_STRAIN_BS(2)

!******定义单元类型-120-129---主索******
*DIM,CABLE_STRAIN_ZS,,11

CABLE_STRAIN_ZS(1)=2.419155135E-3 !380
CABLE_STRAIN_ZS(2)=2.419155135E-3 !380
CABLE_STRAIN_ZS(3)=2.2918311805E-3 !360
CABLE_STRAIN_ZS(4)=2.2918311805E-3 !360
CABLE_STRAIN_ZS(5)=2.228169203E-3 !350
CABLE_STRAIN_ZS(6)=2.228169203E-3 !350
CABLE_STRAIN_ZS(7)=1.909859317E-3 !300
CABLE_STRAIN_ZS(8)=1.65521141E-3 !260
CABLE_STRAIN_ZS(9)=1.65521141E-3 !260
CABLE_STRAIN_ZS(10)=1.40056340E-3 !220
CABLE_STRAIN_ZS(11)=1.273239545E-3 !200

*DO,I,120,130
ET,I,LINK10
MP,EX,I,2E11
MP,DENS,I,7.85E3
MP,PRXY,I,0.3
R,I,0.007853982,CABLE_STRAIN_ZS(I-119)
!定义索面积 直径=0.1米，初始应变
*ENDDO

!********定义桥面与塔的连接***********
ET,131,BEAM4
MP,EX,131,3.4E10
MP,DENS,131,2.5E3
MP,PRXY,131,0.3
R,131,16,21.3333,21.3333,4,4

!*************************定义塔上部-BEAM4-1**************
*DO,I,1,42
L,I,I+1
LSEL,U,TYPE,,1,131
LATT,I,I,I,,,,
LESIZE,ALL,,,1,,1
LMESH,ALL,ALL
ALLS
*ENDDO

!*************************塔下部-BEAM4-2***************

!*************************近朝*************************
*DO,I,43,114
L,I,I+1
LSEL,U,TYPE,,1,131
LATT,I,I,I,,,,
LESIZE,ALL,,,1,,1
LMESH,ALL,ALL
ALLS
*ENDDO

!*************************远朝*************************
L,43,116
LSEL,U,TYPE,,1,131
LATT,43,43,43,,,,
LESIZE,ALL,,,1,,1
LMESH,ALL,ALL
ALLS

*DO,I,116,186
L,I,I+1
LSEL,U,TYPE,,1,131
LATT,I-72,I-72,I-72,,,,
LESIZE,ALL,,,1,,1
LMESH,ALL,ALL
ALLS
*ENDDO

!*******************定义索-LINK10********************
!*******************背索*****************************
L,9,222
LSEL,U,TYPE,,1,131
LATT,118,118,118,,,,
LESIZE,ALL,,,1,,1
LMESH,ALL,ALL
ALLS

L,9,223
LSEL,U,TYPE,,1,131
LATT,119,119,119,,,,
LESIZE,ALL,,,1,,1
LMESH,ALL,ALL
ALLS

!*******************主索*****************************
*DO,I,1,11
L,I*4+1,206-I
L,I*4+1,221-I
LSEL,U,TYPE,,1,131
LATT,I+119,I+119,I+119,,,,
LESIZE,ALL,,,1,,1
LMESH,ALL,ALL
ALLS
*ENDDO

!****************定义桥面与塔的连接*************
L,110,193
L,182,208
LSEL,U,TYPE,,1,131
LATT,131,131,131,,,,
LESIZE,ALL,,,1,,1
LMESH,ALL,ALL
ALLS

!******************定义桥面-AREA-4********************

WPROAT,0,-90,0
CYL4,-5.6695,-70,76,90,64,118.09989655,0
WPROAT,0,90,0

A,188,192,207,191

LSEL,U,TYPE,,1,131
AATT,115,115,115,,,,
!LESIZE,ALL,2,,,,2
LESIZE,213,2,,,,2
LESIZE,214,2,,,,2
LESIZE,215,2,,,,2
LESIZE,216,2,,,,2
LESIZE,217,,,,4,2
LESIZE,218,2,,,,2
LESIZE,219,,,,4,2
ALLS
AMESH,ALL

A,192,193,208,207
A,193,194,209,208
LSEL,U,TYPE,,1,131
AATT,116,116,116,,,,
LESIZE,ALL,2,,,,1
ALLS
AMESH,ALL

*DO,I,1,12
A,I+193,I+194,I+209,I+208
*ENDDO
LSEL,U,TYPE,,1,131
AATT,117,117,117,,,,
LESIZE,ALL,2,,,,1
ALLS
AMESH,ALL

!*****************活载****************
!*****不计冲击力-验算最大竖向挠度*****
!SFA,ALL,1,PRES,1834
!F,196,FY,-114286
!F,197,FY,-114286
!***************************************

F,196,FY,-160000
F,197,FY,-160000

FINISH
!***********************加约束*************************
/SOLU
D,115,ALL
D,187,ALL
D,188,ALL
D,189,ALL
D,235,UY
D,239,UY
D,280,UY
D,292,UY
D,735,UY
D,739,UY

!***********重力加速度**********
ACEL,,12
SFA,ALL,1,PRES,2567
!ACEL,,10
SOLVE
FINISH

/POST1 !进入后处理模块POST1
ESEL,S,TYPE,,118,130
ETABLE,LINK-FX,SMISC,1
ESEL,S,TYPE,,1,114
ETABLE,MXI,SMISC,4
ESEL,S,TYPE,,1,114
ETABLE,MXJ,SMISC,10
ESEL,S,TYPE,,1,114
ETABLE,MYI,SMISC,5
ESEL,S,TYPE,,1,114
ETABLE,MYJ,SMISC,11
ESEL,S,TYPE,,1,114
ETABLE,MZI,SMISC,6
ESEL,S,TYPE,,1,114
ETABLE,MZJ,SMISC,12
ESEL,S,TYPE,,ALL